ActionScript 3 Bindable Dynamic Objects

So I’ve been working heavily in Flex lately (and AIR). Been making my own components and building user interfaces for Cascade. For a project I’m working on at work it implements its own localization. It uses a method called getString(‘myString’) to load a string up from the XML strings file.

This was not good for interfaces with lots of strings in it. It required giving every label, every input, every button and id and then after the strings were loaded assigning them all. One of the MXML files I was looking at had over 50 strings to be set and the listener to the string loading ended up being half the page almost! (maybe I exaggerate)

I like binding, and so I set about to create a dynamic object that implemented binding. Putting a [Bindable] tag at the top of a dynamic class didn’t do it. So I made it a proxy and still no go. Finally, after thinking about how it works under the hood, I was sure I knew how I could make it work…. and it did.

I specified the event which would trigger the binding updates to “propertyChange”, the default. This gives me the responsibility of dispatching the event after a bound property is set. Then, implementing IEventDispatcher so that I COULD dispatch an event, and extending Proxy so that I could make sure it happened after setting a property, I came up with the following solution:

package flight.utils
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
	import flash.utils.Proxy;
	import flash.utils.flash_proxy;import mx.events.PropertyChangeEvent;
	import mx.events.PropertyChangeEventKind;use namespace flash_proxy;
	
	[Bindable("propertyChange")]
	dynamic public class BindableObject extends Proxy implements IEventDispatcher
	{
		
		protected var strings:Object;
		protected var eventDispatcher:EventDispatcher;
		
		public function BindableObject()
		{
			strings = {};
			eventDispatcher = new EventDispatcher(this);
		}
		
		flash_proxy override function getProperty(name:*):*
		{
			return strings[name] || name;
		}
		
		flash_proxy override function setProperty(name:*, value:*):void
		{
			var oldValue:* = strings[name];
			strings[name] = value;
			var kind:String = PropertyChangeEventKind.UPDATE;
			dispatchEvent(new PropertyChangeEvent(PropertyChangeEvent.PROPERTY_CHANGE, false, false, kind, name, oldValue, value, this));
		}
		
		public function hasEventListener(type:String):Boolean
		{
			return eventDispatcher.hasEventListener(type);
		}
		
		public function willTrigger(type:String):Boolean
		{
			return eventDispatcher.willTrigger(type);
		}
		
		public function addEventListener(type:String, listener:Function, useCapture:Boolean=false, priority:int=0.0, useWeakReference:Boolean=false):void
		{
			eventDispatcher.addEventListener(type, listener, useCapture, priority, useWeakReference);
		}
		
		public function removeEventListener(type:String, listener:Function, useCapture:Boolean=false):void
		{
			eventDispatcher.removeEventListener(type, listener, useCapture);
		}
		
		public function dispatchEvent(event:Event):Boolean
		{
			return eventDispatcher.dispatchEvent(event);
		}
	}
}

So I can create an object, “strings”, and bind all my buttons and labels to properties of the strings object (e.g. <mx:Button label=”{strings.ok}”/>) and when my XML is loaded and the dynamic properties on the strings object are set, my components will automatically update.

Working on Cascade

So I know I haven’t written in awhile. I’ve been busy working on a web content management system (CMS) I hope to get my business off the ground and running. I’m pretty excited about it. About 49% of the people I talk to about it aren’t sure what the difference is between Dreamweaver and a web CMS. They’re the non-web developer people like my family and some of my friends. Another 49% (the web guys) aren’t sure why I would choose such an established market to make a product for and even after I explain my marketing strategy still scratch their heads over it. They are still

generic viagra onlineviagra onlineviagra canadian pharmacygeneric viagracanadian pharmacy adderallcialis online pharmacyhttp://cialisincanada-cheap.com/http://pharmacyincanada-onlineon.com/

nice about it and wish me good luck. They’ll all see why here soon! So, I’ve been sort of waiting around for Cascade (my CMS) to be done and then continue blogging, but that’s taking too long, so I’ll keep writing until it’s done. Then I’ll be moving my site over to withincode.com and using Cascade to manage it all.